Руководство администратора

ALTER procedure [dbo].[TasksHierarchy]
(
  @TaskId int = null,        
  @RootTaskId int = null,  
  @SessionUserId int,
  @XmlParam xml = null,
  @OnlyOneRow bit = 0,
  @DataType varchar (20) = 'GetChilds'  
)
as
begin
  select
    t.TaskId AS Id,      
    t.ParentTaskId AS ParentId,      
    t.[Description] as TaskName,      
    t.IsOverdue,      
    t.IsClosed,      
    states.FinishWork as IsWorkFinished,    
    states.WorkNotStarted as IsWorkNotStarted,
    t.IsEncrypted,      
    states.[Description] as StateName,      
    subcats.SubcatID as SubcategoryId,      
    subcats.[Description] as SubcategoryName,
    t.PlannedStart as PlanStart,      
    t.OrderedTime as PlanFinish,      
    t.TaskStartTime as FactStart,      
    t.EndTime as FactFinish,
    CASE
    WHEN t.SubcatID = 1111 THEN '../img/crown.png'
    WHEN t.SubcatID = 2222 THEN '../img/trophy.png'
    WHEN t.SubcatID = 3333 THEN '../img/list.png'
    WHEN t.SubcatID = 4444 THEN '../img/task.png'
    ELSE NULL END
    as MainIconUrl,
    cast (isnull(t.PercentDone, 0) as smallint) as PercentDone,      
    th.UserId as PerformerId,
    cast(isnull((select top 1 1 from Tasks as p where t.TaskId = p.ParentTaskID), 0) as bit) as HasChildren
  from tasks as t WITH(NOLOCK)
    join States states with(nolock) on states.StateId=t.StateId      
    join Subcategories subcats with(nolock) on subcats.SubcatId=t.SubcatId      
    left join TaskHelpers th with(nolock) on th.TaskId=t.TaskId and th.IsResponsible=1
  where ((@TaskId is null AND t.SubcatID = 1234 AND t.IsClosed = 0) or (t.ParentTaskId=@TaskId and @TaskId is not null))
  order by subcats.[Description], t.TaskId asc;
end;

Иерархия строится по трем категориям: Подразделения, Вакансии (содержит ДП "Подразделение") и Анкеты кандидатов (содержит ДП "Вакансия"). Для иерархии настроен фильтр, который отбирает вакансии, которые относятся к выбранному региональному филиалу и должны быть закрыты в выбранный период времени.

Если для иерархии задан номер корневой задачи, то процедура отбора возвращает данные по одному подразделению, чей номер (ID задачи) передается в параметре RootTaskID. Если номер корневой задачи не задан, то строится иерархия по всем подразделениям.

ALTER PROCEDURE [dbo].[cv]

(
  @TaskId int = null,
  @RootTaskId int = null,
  @SessionUserId int,
  @XmlParam xml = null,
  @OnlyOneRow bit = 0,
  @DataType varchar (20) = 'GetChilds'
)
AS
BEGIN
SET NOCOUNT ON;
 
-- параметры из фильтра (используются для отбора вакансий по сроку, к которому необходимо найти сотрудника)
 
declare @StartDate date = null, @EndDate date = null
declare @Params table ([Name] varchar(max), [From] varchar(max), [To] varchar(max), [Value] varchar(max))
 
insert into @Params ([Name], [From], [To], [Value])
exec crm_repGetParams @XML = @XmlParam
 
select @StartDate = cast([From] as varchar(max)), @EndDate = cast([To] as varchar(max))
  from @Params where Name = 'Period'
 
-- данные
 
  CREATE TABLE #t (ParentId int, Id int, TaskText text, IsEncrypted bit, HasChildren bit, Icon text, Duedate datetime, TaskStatus text, Style text)
 
-- подразделение, категория 11
    INSERT INTO #t (ParentId, Id, TaskText, IsEncrypted, HasChildren, Icon, Duedate, TaskStatus, Style)
        SELECT null, t.TaskID, t.TaskText,
          t.IsEncrypted,
          cast(IsNull((select top 1 1 from dbo.TasksInSubcat22Denormalized as p
                                      where t.TaskID = p.ExtParam21NativeValue), 0) as bit),
           '../img/insert.gif',
          null, t.StateName, ''
        FROM dbo.TasksInSubcat11Denormalized t
        WHERE t.IsClosed = 0
          AND (t.TaskId = @RootTaskId or @RootTaskId is null) -- по одному подразделению или по всем
          AND @TaskId is null;                               -- смотреть подразделения только на первой итерации
 
-- вакансии, категория 22, содержит ДП "Подраздление" с ID=21        
    INSERT INTO #t (ParentId, Id, TaskText, IsEncrypted, HasChildren, Icon, Duedate, TaskStatus, Style)
        SELECT @TaskID, t.TaskID, t.TaskText,
          t.IsEncrypted,
          cast(isnull((select top 1 1 from dbo.TasksInSubcat33Denormalized as p
                                      where t.TaskId = p.ExtParam32NativeValue), 0) as bit),
           '../img/new.gif',
          t.OrderedTime, t.StateName,
          case when t.IsClosed = 1 then 'task-state task-closed' else '' end
        FROM dbo.TasksInSubcat22Denormalized t
        WHERE (t.ExtParam21NativeValue = @TaskId)
          AND ((t.OrderedTime >= @StartDate) OR (@StartDate is null))
          AND ((t.OrderedTime <= @EndDate) OR (@EndDate is null));
 
-- анкеты, категория 33, содержит ДП "Вакансия" с ID=32
    INSERT INTO #t (ParentId, Id, TaskText, IsEncrypted, HasChildren, Icon, Duedate, TaskStatus, Style)      
        SELECT @TaskID, t.TaskID, t.TaskText,
          t.IsEncrypted, 0,
           '../img/addperf.gif',
          t.OrderedTime, t.StateName,
          case when t.IsClosed = 1 then 'task-state task-closed' else '' end
        FROM dbo.TasksInSubcat33Denormalized t
        WHERE (t.ExtParam32NativeValue = @TaskId)
 
  SELECT ParentId, Id, TaskText, IsEncrypted, HasChildren, Icon, Duedate, TaskStatus, Style FROM #t
  DROP TABLE #t
END

Если иерархия "Подразделения -> Вакансии -> Анкеты кандидатов" (см. предыдущий пример) строится не на основе ссылок через Lookup, а на основе связей "родительская задача — подчиненная задача", то в иерархии может быть включен режим drag-and-drop, когда задачи перемещаются между ветвями иерархии с помощью перетаскивания. Также в этом режиме возможна постановка подзадач непосредственно из иерархии.

Процедура, формирующая список категорий для постановки подзадач в иерархии определяет категорию текущей задачи (ее номер передается в параметре TaskId) и в зависимости от нее выбирает категорию для постановки подзадачи:

ALTER PROCEDURE [dbo].[cv_cr_catId]
(
  @HierarchyId int =null,
  @TaskId int = null,
  @RootTaskId int = null,
  @SessionUserId int=null,
  @XmlParam xml = null
)
AS
BEGIN
select
  case Tasks.SubcatID when 11 then 22 when 22 then 33 end as SubcatId,
  case Tasks.SubcatID when 11 then 'Вакансии' when 22 then 'Анкеты кандидатов' end as Description
from Tasks where Tasks.TaskID = @TaskId
END

ALTER PROCEDURE [dbo].[hierarchy_org]
(
  @TaskId int = null,
  @RootTaskId int = null,
  @SessionUserId int,
  @XmlParam xml = null,
  @OnlyOneRow bit = 0,
  @DataType varchar (20) = 'GetChilds'
)
as
BEGIN
SELECT id as Id, parentid as ParentId, name as divisionname, CAST(0 as bit) IsEncrypted, CAST(1 as bit) HasChildren
  FROM OrgStructureUnit
  WHERE (@TaskId is null) AND (Id = @RootTaskId)
 
UNION ALL
 
SELECT id as Id, parentid as ParentId, name as divisionname, CAST(0 as bit) IsEncrypted, CAST(1 as bit) HasChildren
    FROM OrgStructureUnit
  WHERE (@TaskId is not null) AND (ParentId = @TaskId)
END